Guía para alcanzar la felicidad con Macros

¡Buenas! Soy Frikilangelo, tal vez me recordéis de algunos post como un ferviente defensor de la Luz en forma de paladín, a pesar de que esta Luz no nos ha iluminado demasiado últimamente…

Bueno, al caso, aquí vengo con una Guía de macros, su intención es para aquellos que no tengan experiencia con ellas o no sepan que son se animen a usarlas. Así pues, sin más rodeos, iré exponiendo cada una de las opciones (o por lo menos, las que más posiblemente se puedan usar). Por supuesto estoy abierto a comentarios, criticas (constructivas y no tanto) y cualquier tipo de ayuda o consejo

Un pequeño dato a tener en cuenta es que el WoW en español reconoce los comando en ingles (/cast) pero no el nombre de los hechizos, así que dependiendo en qué idioma estéis jugando tendréis que usar los hechizos en el idioma en cuestión

Los ejemplos que iré dando serán entorno a los paladines, pero perfectamente son válidos para cualquier clase a menos que se especifique lo contrario

/cast

Tan simple como:

/cast Hechizo

Seguramente muchos diréis ‘si, esto es muy fácil, ¿pero no se puede mejorar?’ Pues sí, en realidad el comando /cast es tal que así:

/cast [opciones] hechizo; /cast [opciones] hechizo;...

El «;» quiere decir que si no hace la 1º, pasara la siguiente, y así sucesivamente.

Las opciones son:

• help -> comprueba si el objetivo es amistoso
• harm -> comprueba si el objetivo es enemigo
• combat -> comprueba si estas en combate
• stance – stance:# -> comprueba si estas en una estancia u otra (guerreros, druidas,…)
• stealth -> comprueba si estas en sigilo
• modifier – modifier:shift/ctrl|/alt -> comprueba si alguna de estas teclas esta pulsada cuando usas al macro
• equipped: -> comprueba si tienes equipado algún objeto
• target= -> cambia el objetivo actual a uno expuesto en las condiciones
• actionbar: -> comprueba si la actionbar es la expuesta en las condiciones
• pet: -> comprueba si existe una mascota con las características dadas . Si no especificas será válida cualquiera
• mounted/swimming/flying -> comprueba si estas realizando alguna de estas acciones
• indoors/outdoors -> comprueba si estas en un interior o un exterior
• button:< #> -> comprueba si se ha pulsado el botón para realizar esta acción
• channeling: -> comprueba si estas canalizando un hechizo. Si no especificas cual, será válido cualquiera
• exists – dead -> comprueba si tu objetivo está vivo o muerto
• party -> comprueba si el objetivo es miembro de tu grupo
• raid -> comprueba si el objetivo está en tu banda
• group -> comprueba si estas en un grupo
• group:party – raid -> comprueba si estas en alguno de estos grupos

/Cast ejemplos

Vamos a ver un ejemplo, como pasamos de un botón que cura a un botón que hace más cosas dependiendo de al situación

/cast Luz Sagrada

Lanza Luz Sagrada en tu objetivo. Simple, ¿no?

/cast [help] Luz Sagrada

Lanza Luz Sagrada si tu objetivo es amistoso. Mejor, ¿no?

/cast [help] Luz Sagrada; Sentencia

Igual que al anterior, solo que usará Sentencia en caso de que el otro falle (dícese, si el objetivo no es aliado tirará la Sentencia).

/cast [help, combat] Luz Sagrada; [help, nocombat] Luz Divina; Sentencia

Más de lo mismo, usa Luz Sagrada si el objetivo es amistoso y está en combate, Luz Divina si es amistoso y no está en combate, o Sentencia si no es nada de lo anterior.

/cast [help] Luz Sagrada; [harm, combat] Golpe de cruzado; [harm, nocombat] Arrepentimiento

Luz Sagrada si es amistoso, Golpe de cruzado si estas en combate contra un enemigo, o Arrepentimiento si no estás en combate y tienes un objetivo enemigo.

/cast [actionbar] Luz Sagrada; [actionbar] Golpe de cruzado

Lanzaremos Luz Sagrada si nuestra barra de acción es la 1, o Golpe de cruzado si es la 2º.

/stopmacro [noharm]
/cast [harm] Arrepentimiento
/p CC en %t!!!
/script SetRaidobjetivoIcon (t,#)

Tiramos nuestro Arrepentimiento a un enemigo, si no es enemigo para la macro (esto, por ejemplo, es porque los enemigos ovejeados cuentan como [noharm], tenedlo en cuenta), y aparte avisa a nuestra grupo de que ese enemigo que está en Control de Masas.

El %t dice el nombre del objetivo que tengamos en ese momento, así que dirá el nombre del enemigo que tengamos en objetivo, y por consecuente, el que se llevará nuestro Arrepentimiento.

El (t,#) es uno de los iconos para marcar los monstruos, en el cual tendréis que sustituir la # por un numero del 1 al 8.

/cast [group] Luz del Alba; Word of Glory

Si el objetivo esta en grupo usas el Luz del alba pero si estás sólo, Palabra de Gloria.

Opciones de equipped

Esta es la lista de las opciones que puedes poner:

• Bag
• Two-Hand
• Ranged
• Chest
• Shirt
• Off Hand
• Chest
• Shoulder
• Back
• Tabard
• Feet
• Thrown
• Finger
• Trinket
• Hands
• Waist
• Head
• One-Hand
• Held In Off-hand
• Main Hand
• Legs
• Off Hand
• Neck
• Wrist

A continuación os dejo algunos ejemplos de lo que se puede hacer:

/cast [equipped:Two-Handed Swords - Two-Handed Maces - Two-Handed Axes - Polearms] Sello de Rectitud; Sello de Verdad

Si usamos armas de dos manos usaremos el Sello de Rectitud, si no el Sello de Verdad

/cast [equipped:Shields] Sello de Rectitud; Veredicto de Templario

Usaremos Sello de rectitud si tenemos un escudo o Veredicto de Templario si no tenemos

/cast [equipped:Shields, equipped:sword - mace - axe] Martillo del honrado

Usara solo el Martillo del honrado si tenemos una espada equipada

/cast [noequipped:Shields, equipped:Off Hand] Luz Sagrada

Un ejemplo un poco estúpido, pero es para que veáis las posibilidades que hay. Usara Luz Sagrada si en vez de llevar un escudo lleva un off hand

Opciones de Button

Estas depende del botón del ratón que estemos usando, entre los cuales son:

• 1 – Izquierdo
• 2 – Derecho
• 3 – Centro
• 4 – Boton 4
• 5 – Boton 5
• …

Y aquí un ejemplo sencillo.

/cast [button,target=player] Luz Sagrada; [help] Luz Sagrada

Si pulsas el botón derecho del ratón usaras Luz Sagrada en ti, si no lo usará en el objetivo si este es amistoso. Básicamente es como la opción de auto lanzarse hechizos pero en macro.

Opciones de objetivo

Esta posiblemente es la más interesante de todas, permite hacer heals a los miembros necesarios y otras utilidades.

Para empezar:

/cast [help] Luz Sagrada es lo mismo que /cast [target=target, help] Luz Sagrada

Ya que el tu objetivo es tu objetivo (target=target). Con esto en mente vamos a ver algunos ejemplos.

/cast [target=player] Luz Sagrada

Usaras Luz Sagrada siempre en ti mismo, útil por que así no pierdes objetivo.

/cast [target=targettarget] Defensa recta

Básicamente convierte nuestra Defensa Recta en un taunt.

/cast [help] Luz Sagrada; [objetivo=targettarget] Luz Sagrada

Una de las mejores cosas del objetivo. Usarás Luz Sagrada en tu objetivo si es amistoso, o Luz Sagrada en el objetivo de tu objetivo. Dicho de otra forma. Estas en grupo contra un jefe. Si usas la macro en un jugador le lanzarás Luz Sagrada; pero si tienes como objetivo al jefe, curarás al objetivo del jefe (el tanqueo el que sea en ese momento), con lo cual lo único que tienes que hacer es spamear el boton, ya que siempre curarás al objetivo del jefe, que es el que, en general, recibirá más daño.

/cast [help, combat] Luz Sagrada; [help, nocombat] Luz Divina; [target=targettarget, help, combat] Luz Sagrada; [target=player] Luz Divina

Usarás Luz Sagrada si el objetivo amistoso está en combate; si no usaras Luz Divina si el objetivo es amistoso y tú no estás en combate; si no, usará Luz Sagrada en el objetivo de tu objetivo si está en combate y es amistoso; si no usaras Luz Divina en ti… ¿un poco lioso? Bueno, es posible, pero mejor ver las posibilidades.

/cast [target=none] Luz Sagrada

Cuando la uses preguntará por un objetivo, a pesar de que tengas uno ya activo. Desde luego no es algo que vayas a usar, pero ahí está la posibilidad.

/cast [target=focus] Sentencia

Usaras Sentencia en un objetivo (foco) que hayas establecido antes, sin tener que preocuparte de perder objetivo ni nada. ¿Cómo hacer esto? Crea la macro:

/focus objetivo

Pincha en un monstruo/jefe/jugador/lo-que-sea y usa la macro. Automáticamente asignará el foco a la cosa seleccionada, y cuando uses la macro anterior automáticamente la usara en el foco que hayas designado. Útil para ganar esa celeridad extra de la sentencia sin perder objetivo

Comando /cancelaura

Básicamente sirve para quitarnos un beneficio que tengamos. Parece estúpido, pero para mí es muy útil, lo veréis con este ejemplo

/cast Escudo divino
/cancelaura Escudo divino

Esto nos permite ponernos y quitarnos la pompa para salvar determinadas ocasiones, sobre todo si eres tanque =). Dicho de otro modo, pincha una vez y te pondrás en pompa, pincha de nuevo y te la quitas. ¿Sigues creyendo que es estúpido? Si pinchas dos veces seguidas la macro se traduce en un mass dispel en ti mismo, el problema es que si eres tanque perderás el agro por un momento… nada preocupante, pero si sigues teniendo apuro por eso y eres tanque, cambia la macro a:

/cast Escudo divino
/cast Mano de expiación - [target=targettarget] Defensa recta
/cancelaura Escudo divino

Solucionado, a la vez que usas la pompa usarás provocar.

Comando /castsequence

Sirve para crear una secuencia de lanzamiento (¿¡en serio!?). Lo hemos ido aplicando a lo largo de la explicación (usando los ; por ejemplo), pero aquí vamos a darle más despacito

/castsequence [<options>] reset=<#>/target/combat/alt/shift/ctrl <Luz Sagrada >, <Luz Divina>, <Imposición Divina>

Como seguramente no lo entendáis, vamos a ir desde 0.

/castsequence Favor divino, Luz Divina

La primera vez que pulsemos la macro usara Favor  Divino, la 2º vez Luz Divina

Y seguro que empezaran las preguntas… así que hagámoslo ameno:

P   Oye, una cosa, ¿qué pasa si Favor divino está en CD? La próxima vez que la use, ¿usará Luz Divina?
R – Hmmmmm… no. La macro solo se efectuara si es posible usar todos los elementos de esta. Así que hasta que no esté el Favor divino sin CD nada, tenedlo en cuenta porque es una de las gracias del /castsequence

P – ¿Y si quiero usar mi macro, pero no quiero que use el Favor Divino? Es que me gusta el botón que le he puesto…
R – Bueno, si lo que no quieres es usarlo accidentalmente si no estás en combate puedes poner esto

/castsequence [combat] Favor Divino, Destello de luz

P – Bueno vale, pero y si quiero usar el Favor divino de mi macro, pero decido no usar el Luz Divina (osea, no lo pulso dos veces). La próxima vez que pulse la macro usara el Luz Divina por el orden que tiene… pero yo solo quiero que use el Favor…  es que soy especialito

R – No problema jefe, usaremos la opción reset para hacer que la macro vuelva a su estado inicial pasados X segundos. Como el Favor Divino tiene 2 minutos de Tiempo de reutilización, en segundos serán 120.

/castsequence reset=120 Favor Divino, Luz Divina

La primera vez que pulses la macro usara Favor Divino. Si la usa antes de 120 segundos usará Luz Divina (si la vuelves a pulsar después no pasará nada, por que como pasaba ya antes, si no puede hacer un hechizo directamente la macro se anula). Si la usas después de 120 sin haber pulsado antes a macro otra vez volverá directamente a su estado natural. Aparte no es necesario poner el tiempo de CD de una habilidad, puedes poner el que sea (por algun motivo en especial o algo…), pero así es más practico ¿no?

P – Asi que después de 120 segundos, ¿se reiniciará la macro pase lo que pase?
R – ¡¡Para el carro!! Has de saber una cosa, y es que cada vez que pulses la macro, el contador volverá a ponerse al máximo (en este caso a 120), así que no seas spamer en este caso, o si no la macro no va a estar nunca disponible

P – Jooo… con lo que a mí me gusta pulsar botones…
R – Hay macros para eso, pero en este caso es para hechos puntuales. También la puedes combinar usándolo con abalorios o mas habilidades para, por ejemplo, subir al tanke en el menor tiempo posible con una macro que use todos los CD del Paladín

P – Bueno, me he hecho una macro para matar mobs

/castsequence Sentencia, Golpe de cruzado, Cólera sagrada

R – Hmmmm…bien, no está mal =)

P – Vale, el problema es que cuando termino de usar la secuencia, vuelve al principio. Si estoy luchando contra dos enemigos, y con el primero uso la Sentencia y el Golpe de cruzado… pero ahora quiero cambiar de objetivo al 2º monstruo, pero no quiero seguir con la Cólera sagrada, ¿como lo hago para empezar desde 0 sin usar la $%&/@# del reset con tiempo?
R – Bueno, podemos hacer esto otro, no es necesario que el comando reset se haga con cifras, se puede hacer con las demás opciones, así que podemos hacer esto

/castsequence reset=combat/target Sentencia, Golpe de cruzado, Cólera de cruzado

En cristiano, si cambias de objetivo (por si se ha muerto, o empiezas a darte con otro) pondrá la secuencia desde 0, con lo cual no te quedaras estancado en la Cólera Sagrada, si no que empezará con la Sentencia (si está disponible)

P – Hmmm… bueno vale, ¿pero y si quiero reiniciarla cuando me de la gana? Así es más practico =)
R – Bueno, modifiquemos un poco más esto

/castsequence reset=combat/target/shift Golpe de Cruzado, Tormenta Divina, Sentencia

¿Con esto que pasa? Si estamos en combate, con un objetivo y con la tecla Shift pulsada volveremos al inicio de la secuencia. Si no, proseguiremos como si nada.

P  ¡¡¡Wololol!1!! ¿Qué útil no?
R – Pues sí, y también sirve para sanadores y tanques, solo hay que poner los hechizos que se deseen, y con un poco de imaginación se pueden lograr macros muy buenas.

Macros misceláneas

P – Oye, otra cosa, ¿sabes alguna macro más que sea útil?
R – Mira, una útil, para tener en un botón todas las monturas

/cast [mod:Shift] WarHorse; [flyable] Grifo nevado acorazado; Caballo de guerra

Con esta macro si estas en una zona en la que se puede volar, y la usas mientras mantienes pulsado el Shift sacarás la terrestre, si no tocas nada sacará la voladora. Si directamente no se puede volar en la zona sacará la terrestre

P – Bueno, con esto ya puedo hacer una macro de lo que quiera… pero hay alguna macro para hacer algo…. no sé, ¿raro?
R – Bueno…

/castrandom Destello de Luz, Luz Sagrada, Imposición de manos

Usará uno de los hechizos al azar entre los que pongas en la lista… ¿cuántas veces crees que puedes usarla sin gastar un tiempo de reutilización de 20 minutos? XDD. También la puedes usar cambiando el nombre de los hechizos por el nombre de monturas, para sacar el caballo, el carnero, el tigre, …uno al azar, así con un mismo botón te podrás montar en una montura al azar que tengas

Y otro…

/script PlaySoundFile("Sound\Music\GlueScreenMusic\BCCredits_Lament_of_the_Highborne.mp3")

Esta lo que hace es abrir un archive de sonido dentro de la carpeta del juego y reproducirlo. Pude ser cualquiera siempre que la dirección este bien puesta. Os he puesto esta porque es una especial, la que pusieron en el parche en que cambiaron a Sylvanas, y dieron una misión que si recuperabas su antiguo amuleto se ponía a cantar esta canción…

Macros practicas

Ejemplo 1 – Canalizar hasta el final

¿Eres un Sacerdote sombra frustrado, porque para ganar tiempo con tu Tortura mental a veces pierdes el último tick de este? No te preocupes, aquí tenemos la solución

#showtooltip Tortura Mental
/ cast [nochanneling:Tortura mental] Tortura mental

Basicamente usa Tortura mental, y no te deja usar la macro de nuevo hasta que este acabe de canalizarse… ¡ya no tendras excusas en tu DPS!

Ejemplo 2 – Cambio de armas

¿Harto de que tu pícaro vea como corren esos desgraciaos de ti con tus 5 puntos de combo, y te sientes incapaz de hacer algo porque no puedes usar tu Deadly Throw porque tienes una escopeta equipada? No te preocupes, aquí estamos con tu solución

/cast [equipped:Thrown] Lanzamiento mortal
/equip [noequipped:Thrown] (inserta tu arma aqui)
/cast [equipped:Thrown] Lanzamiento mortal

¡Se acabaron esos apuros de que justo se salgan del combate y se vayan corriendo en su montura!

Y para cuando acabes con él, puedes usar esta macro

/cast [combat] Esfumarse; [stance:0] Sigilo
/cast [nocombat,nostealth] Fusión de las sombras

Básicamente, si eres Elfo nocturno, con esta macro tendrás todas tus posibilidades de invisible en un solo botón

Ejemplo 3 – Rebuff rápido

¿Eres un chamán (o un rogue) cansado de tener que ir poniendo tus encantamientos o venenos una y otra vez? No llores más, de nuevo tenemos otra macro para hacerte la vida más fácil.

/use (nombre del veneno - encantamiento - etc sin paréntesis)
/use [button:1] 16; [button:2] 17

De esta forma con un solo botón encantaras ambas armas con lo mismo… o si lo prefieres:

/use [nomodifier] (veneno 1 - encantamiento 1); [modifier:alt] (veneno 2 - encantamiento 2); [modifier:ctrl] (veneno 3 encantamiento 3)
/use [button:1] 16; [button:2] 17

Aplicaremos la opción 1 haciendo click, la 2 haciendo ALT+ click o la 3 haciendo CTRL +click

Ejemplo 4 – Cura desesperada

¿Estás en medio de un combate contra cierto indeseable y necesitas curarte con vendas para aguantar, pero no encuentras el momento? De nuevo, aquí tenemos varias soluciones

/cast disable (como gubia – arrepentimiento – ceguera – etc)
/stopcasting
/cast [target=player] (poner aquí el nombre de la venda sin paréntesis)
/targetlasttarget

De esta forma podréis tiraros vendas sin temor a reprimentas de forma rápida, y recuperar el último objetivo que teníais

Ejemplo 5 – Atacando sin objetivo

Estas peleando contra un sanador indeseable, mientras ves a otro de ellos corriendo a 100 de vida… sin embargo, no puedes cambiar de objetivo porque necesitas estar atento por si tienes que cortar una cura de tu objetivo actual… ¿qué haces en un momento así? ¡Pues puedes probar a usar esto!

/cast [objetivo=mouseover] (Palabra de sombras: Muerte – Lanzamiento heroico – Martillo de cólera – etc)

Simplemente pon el ratón encima de ese cobarde, no necesitas pincharle, solo tener el ratón encima, pulsa la macro y… ¡voila! Otro más que va a subirse la reputación con el Ángel de Resurrección.

Ejemplo 5 – Supervivencia para apurar lanzamientos

Eres un mago feliz de la vida, lanzando bolas de fuego al jefe de turno… sin embargo, uno de sus habilidades dva a impactar, y estas en medio del lanzamiento de una Piroexplosión que decidiste lanzar… ¿que puedes hacer?

#showtooltip (Bloque de hielo - Contrahechizo - Palabra de poder Escudo - etc)
/stopcasting
/cast (Bloque de hielo - Contrahechizo - Palabra de poder: Escudo - etc)

Con esta macro (el showtooltip automáticamente la imagen de la habilidad que va a usarse en la macro) detendrás automáticamente cualquier lanzamiento de hechizos y te pondrás a salvo dentro de tu querido cubo… ahora podrás apurar hasta el máximo el momento del lanzamiento porque de ser necesario solo tienes que pulsar el botón para detenerlo y ponerte a salvo

Ejemplo 6 – Equipo paracaidista

No sé si habréis visto un video en el que una raid alianza va a atacar Cima del Trueno, la capital de los taurens. Toda la raid subió por los ascensores, cuando, de repente, un tauren chamán les saluda con la mano y usa Tormenta de truenos, y los manda a todos volando, precipitándose contra el suelo de forma bastante cómica (por si os interesa, el video es este)

Si no queréis acabar igual de triste, y eres un mago o sacerdote, puedes usar esta macro

#showtooltip Caída lenta
/cast [@mouseover, raid] [@player] (Levitar - Caida lental)

Considera que fueras uno de esos desgraciados, con esta macro seria como una especia de tiro al pato, solo apunta con el raton (sin pinchar que no hace falta) y spamea el botón a diestro y siniestro… ¡banda salvada!  (o al menos gran parte…)